***************************
*
*
***************************
*
OPCH EQU $8F2
XOP EQU $8F3
YOP EQU $8F4 
OPNUM EQU $8F5
TEMX EQU $8F6  
MNFLF EQU $9E8
TEMXX EQU $9E9
RANDOM EQU $C18 
RNDL EQU $4E 
WIDTH EQU $EC
AHI EQU $800
ALO EQU $900
YBOT EQU $FC
ACTF EQU $8F7
XH EQU $9C3
YH EQU $9C4
TEMYH EQU $9CD
TEMPOSE EQU $9C8
LEV EQU $8CA
XB EQU $8F9
XMID EQU $8FA
YLOW EQU $8FB
COMP EQU $8FC
XTEMP EQU $8C3
ADJ EQU $8FD
RNUM EQU $8C9
REVFLG EQU $8D9
ERASEOLD EQU $A3E
TONE EQU $303
COLLIDE EQU $1009
LEFTWALL EQU $5A1E
LFDOP EQU $5A1B
RTDOP EQU $5A18
DELTA EQU $93E0
RTDRMSK EQU $94D7
LFDRMSK EQU $94DA
SETWALK EQU $100C
SETRIGHT EQU $100F
SETLEFT EQU $1012
TIM1 EQU $9EA
TIM2 EQU $9EB
LIVES EQU $9ED
NOISEFLG EQU $8DA
ROW EQU $8CC
MSG EQU $5718
*
*
 ORG $C38 
*
*
CHECKOPS JMP CHECKOPS1
NEWPRINT JMP NEWPRINT1
FIRSTPRINT JMP FIRSTPRINT1
MOVPRINT JMP MOVPRINT1
CHECKOLD JMP CHECKOLD1 
CHRTLUN JMP CHRTLUN1
CHRTJAB DFB $60,0,0  
CHRTLOW JMP CHRTLOW1
CHLFLUN JMP CHLFLUN1
CHLFJAB DFB $60,0,0  
CHLFLOW JMP CHLFLOW1
RMADJRT JMP RMADJRT1
RMADJLF JMP RMADJLF1
*
*
CHECKOLD1 JSR ENTRIGHTCHK
 LDX OPNUM
CHINT LDA CHNEW,X 
 CMP CHOLD,X
 BNE MOVPRINT1
 LDA XNEW,X
 CMP XOLD,X
 BNE MOVPRINT1
 LDA YNEW,X
 CMP YOLD,X
 BNE MOVPRINT1
 RTS
*
*
NEWPRINT1 LDA XOLD,X
 STA XOP
 LDA YOLD,X
 STA YOP
 LDA CHOLD,X
 STA OPCH
 JMP PRINTOP
*
FIRSTPRINT1 LDA CHNEW,X
 STA CHOLD,X
 STA OPCH
 LDA XNEW,X
 STA XOLD,X
 STA XOP
 LDA YNEW,X
 STA YOLD,X
 STA YOP
 JMP PRINTOP
*
*
MOVPRINT1 JSR NEWPRINT1
 JSR FIRSTPRINT1
 RTS
*
*
PRINTOP STX TEMX
 LDX XOP
 LDY YOP
 LDA OPCH
 JSR ERASEOLD
 LDX TEMX
 RTS
*
*
CHECKOPS1 LDX #$F     
MNLOOP LDA OPMODE0,X
 BPL NEXTMNST
 JSR MOVIT
NEXTMNST DEX
 BPL MNLOOP
CHKOUT JSR MNSTEFFECT
 RTS
*
*
*
*
*
MOVIT STX OPNUM
 LDA MNYTAB,X 
 STA YGET1+1 
 LDA FLGLO,X
 STA ROLFLG1+1 
 STA OPF1+1
 LDA MNMODE,X
 STA CHBIT+1 
MNMOV LDX OPNUM  
 LDY LEVOP,X
YGET1 LDA $E00,Y ; CHANGEABLE 
 STA YNEW,X
 CLC
OPF1 BIT OPFLG0 ;CHANGEABLE 
 BPL ROLFLG1
 SEC
ROLFLG1 ROL OPFLG0 ;CHANGEABLE 
 BCC MV1OUT
OPM1 LDA OPMODE0,X
 AND #4
 BEQ CH20
 JMP RANDCH
CH20 LDA OPMODE0,X
 AND #$20
 BEQ CHKCHG 
 JSR PURSUIT 
CHKCHG LDA OPMODE0,X
 AND #$10
 BEQ CHBIT
 JSR CHARGE
CHBIT BIT OPMODE0 ;CHANGEABLE 
 BVC ADV1 
 JMP RETN
ADV1 JMP ADVN ;RTS AT END OF THESE
MV1OUT RTS
*
*
SQUONK BIT NOISEFLG
 BMI NONOISE
 JMP TONE
NONOISE RTS
*
*
 ORG $6000
*
************************
*
* REACTIONS
*
************************
*
SHOTCHECK JMP SHOTCHECK1
*
*
SHOTCHECK1 BIT ACTF
 BMI SLEFT
SRIGHT LDA XH
 CLC
 ADC #3
 STA XB
 LDA #$EE
 STA DIRS   
 LDA #39
 STA LIM+1
ST0 LDX #7  
ST1 LDA XOLD,X
 CMP XB
 BNE NXOPR
 LDA OPMODE0,X
 AND #$80
 BEQ NXOPR
 LDA LEVOP,X
 CMP LEV
 BNE NXOPR
 CPX #4 ;A HIT 
 BCS GOTSN
 JMP BIGSHOT
NXOPR DEX
 BPL ST1
DIRS INC XB
 LDA XB
LIM CMP #39
 BNE ST0
EFOUT RTS
*
*
GOTSN JMP SNAKEHIT
SLEFT LDA XH            
 STA XB 
 LDA #$CE 
 STA DIRS   
 LDA #0
 STA LIM+1
 JMP ST0
*
*
BIGSHOT JSR FLASHPR 
 JSR DIRCH     
 LDA #$80
 STA OPFLG0,X
 JSR MOVIT
 JSR FLASHPR 
 DEC MNSTRES,X
 BPL BGOUT
BEGONE LDA OPMODE0,X 
 AND #$7F
 STA OPMODE0,X
 DEC MNSTREINF,X
 STX XTEMP
 LDX #93
 STX $51
 JSR SQUONK     
 LDX XTEMP
 JSR NEWPRINT1
BGOUT RTS
*
*
SNAKEHIT JSR FLASHPR
 JSR BEGONE
 JSR FLASHPR
 RTS
*
*
FLASHPR STX XTEMP
 LDA #$25
 LDX LEV
 LDY MN0Y,X
 LDX XB
 JSR ERASEOLD
 LDX XTEMP
 RTS
*
*
*
MNSTEFFECT BIT CAPTUREFLG
 BMI ZZZ
 BIT SAFLG
 BMI STARTLOOK
 DEC SAFLG
 BMI STARTLOOK
ZZZ RTS 
STARTLOOK LDX #$D ;LAST TWO HARMLESS
SEE LDA LEV
 CMP LEVOP,X
 BNE NE5
 LDA YNEW,X
 CLC 
 ADC #7 
 CMP YLOW
 BCS NE5
 LDA OPMODE0,X
 BPL NE5
 AND #$40
 BEQ CHLFF
 LDA XOLD,X
 CLC
 ADC OPWIDTH,X
 CMP XMID
 BNE NE5
 JSR ARGH
 JMP NE5
 AND #$80
 BEQ NE5
CHLFF LDA XMID 
 CMP XOLD,X 
 BNE NE5
 JSR ARGH
NE5 DEX
 BPL SEE
 RTS
*
*
ARGH LDA $9C6 ;POSE    
 CMP #$20 ;DOWN FLAT
 BNE ARGH2
 BIT HHFLG
 BPL CHKDOWN 
 CPX #8
 BCS CHKDOWN 
 STX $6 ;TEMPSTOR 
 JMP CAPTURE
CHKDOWN LDA RNDL 
 AND #$F 
 CMP #2
 BEQ ARGH2 ;1 IN 15CHANCE TO BE GOT
 RTS
ARGH2 CPX #8 
 BCS SMBT
 CPX #4
 BCS TSNBT
BIGBT LDA #$F     
 STA COMP
 JMP YLK
TSNBT LDA #7
 STA COMP
 LDY LEV
 LDA MN4Y,Y
 CMP YH
 BEQ ARGHOUT
 JMP YLK
SMBT LDA #3
 STA COMP
 LDA TEMPOSE
 CMP #4
 BEQ ARGHOUT
YLK LDA $8CC ;ROW
 CMP #6
 BEQ CPC
 BIT HHFLG
 BPL YLK1
CPC CPX #$C ;DART ONE? 
 BEQ CHDARTY
 CPX #$D ;DART TWO?
 BEQ CHDARTY
YLK1 LDA YLOW 
 SEC
 SBC #4
 CMP YNEW,X
 BCS OUCH
ARGHOUT RTS
*
CHDARTY LDA YOLD,X
 CMP YH
 BCS OUCH
 BCC ARGHOUT
*
OUCH JSR $C18 ;RANDOM
 LDA $4E ;RNDL
 AND COMP
 CMP #2
 BEQ ARGHOUT
 STX $6
 LDA TEMPOSE
 CMP #3 ;CHECK FOR CROUCH 
 BEQ ARGHOUT 
JCOL JSR COLLIDE
 LDX $6
 LDA OPMODE0
 AND #$10
 BEQ CHOPM1 
 CPX #$C     
 BEQ STUN                  
CHOPM1 LDA OPMODE1 
 AND #$10  
 BEQ CMPC    
 CPX #$D    
 BEQ STUN        
CMPC LDA COMP 
 CMP #$F
 BEQ BIGBITE
 CMP #7
 BEQ MEDBITE
SMALLBITE DEC LIVES
 BPL FINARG
 JMP FINISHED
MEDBITE DEC LIVES
 JMP SMALLBITE
BIGBITE DEC LIVES
 JMP MEDBITE
*
FINARG RTS 
 BRK
*
*
STUN LDA #$FF          
 STA $9CF ;DOWNCOUNT
 DEC LIVES
 BPL STOUT
 JMP FINISHED
STOUT RTS 
* 
*
ENTRIGHTCHK LDX OPNUM
 LDA OPMODE0,X
 BPL RCHKOUT
 AND #$40
 BNE ENTLEFTCHK
 LDA XNEW,X
 CMP #$28
 BNE RCHKOUT
 CPX #8
 BCS SMAN
 LDY LEVOP,X
 LDX RNUM
 LDA RTDRMSK,Y
 AND $9600,X
 BEQ TURNLEFT 
CAB LDX OPNUM 
 CPX #4
CA BCS MIDAN
BIGAN LDX BANN 
ANO STX $50 
 JMP SQUONK 
MIDAN LDX MANN 
 BNE ANO
SMAN LDX SANN 
 BNE ANO
RCHKOUT RTS
*
TURNLEFT LDX OPNUM
TL1 LDA OPMODE0,X 
 ORA #$40
 STA OPMODE0,X
 RTS
*
*
ENTLEFTCHK LDA XNEW,X 
 CPX #8
 BCS CSM
 CPX #4
 BCS CMID
CBIG CMP #$F9
 BNE LCHKOUT
TC LDY LEVOP,X
 LDX RNUM
 LDA LFDRMSK,Y
 AND $9600,X
 BEQ TURNRIGHT
 JMP CAB 
CMID CMP #$FC
 BEQ TC   
 RTS
CSM CMP #$FD
 BEQ SMAN 
LCHKOUT RTS
*
TURNRIGHT LDX OPNUM
TR1 LDA OPMODE0,X 
 AND #$BF
 STA OPMODE0,X
 RTS
*
*
*
*                    
LEFWALLCHK BIT CAPTUREFLG
 BMI LWCOUT
 CPX #8
 BCS LWCOUT
 LDA XNEW,X
 BNE LWCOUT
 LDY LEVOP,X
 LDX RNUM
 LDA LFDRMSK,Y
 AND $9600,X
 BNE LWCOUT
 JMP TURNLEFT
LWCOUT LDX OPNUM 
 RTS
*
* 
RGTWALLCHK BIT CAPTUREFLG
 BMI RWCOUT
 CPX #8
 BCS RWCOUT
 LDA XNEW,X
 CLC
 ADC OPWIDTH,X
 CMP #38
 BNE RWCOUT
 LDY LEVOP,X
 LDX RNUM
 LDA RTDRMSK,Y
 AND $9600,X
 BNE RWCOUT
 JMP TURNRIGHT
RWCOUT LDX OPNUM 
 RTS
*
*
*
*
*
RMADJRT1 LDX #$F
ADD40 LDA XNEW,X
 CLC
 ADC #40
 STA XNEW,X
 DEX
 BPL ADD40
 RTS
*
RMADJLF1 LDX #$F
SB40 LDA XNEW,X
 SEC
 SBC #40
 STA XNEW,X
 DEX
 BPL SB40
 RTS
*
*
RANDCH JSR RANDOM
 LDA RNDL
 CMP #$20 ;CHANGE IF NEEDED 
 BCS RCO
 JSR DIRCH
RCO JMP CHBIT
*
*
DIRCH LDA OPMODE0,X
 AND #$40
 BNE MRT
 JMP TL1      
MRT JMP TR1       
*
*
PURSUIT LDX OPNUM
 LDA XOLD,X
 CMP #40
 BCS OFFRIGHT
 CMP XH
 BEQ NOCHX
 BCS TRT 
TLF JMP TURNLEFT  
NOCHX RTS
TRT JMP TURNRIGHT 
OFFRIGHT CMP #$80
 BCS TLF
 JMP TRT
*
*
CHARGE CPX #0
 BNE CHC1
 JMP CHARG0
CHC1 CPX #1
 BNE CHC2
 JMP CHARG0 ;SAME ROUTINE 
CHC2 CPX #2
 BNE CHC3
 JMP CHARG2
CHC3 CPX #3
 BNE NOCHOICE
 JMP CHARG3
NOCHOICE RTS
* 
*
CHARG0 LDA XOLD+12,X
 CMP #40
 BCC CH01
 LDA #0
 STA OPMODEC,X 
CH01 LDA XOLD,X
 CMP #35
 BCS CHTOUT ;NOT IN ROOM
 LDA LEV
 CMP LEVOP,X
 BNE CHTOUT
 LDA ALREADYFLG,X 
 BMI CHREADY  
 LDA OPMODE0,X 
 AND #$40    
 BNE CHKTORT
CHKTOLF LDA DELTA,X
 CMP #21 ;EXPERIMENT
 BCS CHTOUT
SETSH LDA #4
 STA INDINIT,X
 LDA #$80
 STA ALREADYFLG,X 
CHTOUT RTS
*
CHKTORT LDA DELTA,X
 CMP #$EA ;EXPERIMENT
 BCS SETSH
 BCC CHTOUT
*
CHREADY LDA CHOLD,X 
 CMP #$0B
 BEQ SHL
 CMP #$1B
 BEQ SHR
 RTS
*
SHL LDA #4 
 STA INDN,X   
 LDA XOLD,X
 STA XNEW+12,X
 LDA #$81
LOOSED STA OPMODEC,X 
 LDA #3
 STA INDINIT,X
 LDA #0
 STA ALREADYFLG,X 
 LDA #1
 STA OPFLG0,X
 LDA LEVOP,X
 STA LEVOP+12,X
 RTS
*
SHR LDA #4 
 STA INDN,X   
 LDA XOLD,X
 CLC
 ADC #4
 STA XNEW+12,X
 LDA #$C1
 BNE LOOSED
SHOUT RTS
*
* $FF SHOULD BE IN OPFLGS C&D
* AND DART CHR.# $7B
*
CHARG2 RTS  
CHARG3 RTS  
FINISHED JMP $6506 ;FINI 
*
*
***************************
*
*
CAPTURE LDA #$80
 STA CAPTUREFLG  
 JSR CAPTMSG
 JSR LEFTWALL
 LDA #2
 STA LEV
OPENDOORS JSR LFDOP
 JSR RTDOP
 DEC LEV
 BPL OPENDOORS
 LDX $6
 LDA OPMODE0,X
 AND #$C2 ;TURN OFF CHARGE
 ORA #8 ;STAT. MODE
 STA OPMODE0,X
 LDA OPMODE0,X
 AND #$40
 BEQ LFCP
RTCP JSR SETRIGHT
 JMP CAPOUT 
LFCP JSR SETLEFT  
CAPOUT RTS 
*
*
*
ADVN LDX OPNUM
 LDA SNSEQTAB,X
 STA SNSEQ+1
 LDY INDN,X
SNSEQ LDA $F00,Y ;CHANGEABLE
 STA CHNEW,X
 JSR CHECKOLD1
 JSR MFLCH 
 BMI PROC1
 LDA OPMODE0,X
 ORA #$40
 STA OPMODE0,X
 JMP PROC2
PROC1 LDA OPMODE0,X
 AND #8
 BNE DECIND 
 DEC XNEW,X
DECIND DEC INDN,X 
 BPL AVN 
STIN LDA INDINIT,X 
 STA INDN,X
AVN JSR LEFWALLCHK 
 RTS    
*
*
RETN LDX OPNUM
 LDA OPMODE0,X
 AND #2
 BEQ LDSEQ
 LDA #$80
 STA REVFLG
LDSEQ LDA SNSEQTAB,X 
 STA SRSEQ+1
 LDY INDN,X
SRSEQ LDA $F00,Y ;CHANGEABLE
 BIT REVFLG
 BPL STC
 CLC
 ADC #$10
 LSR REVFLG
STC STA CHNEW,X 
 JSR CHECKOLD1
 JSR MFLCH
 BMI PROC2
 LDA OPMODE0,X
 AND #$BF
 STA OPMODE0,X
 JMP PROC1
PROC2 LDA OPMODE0,X
 AND #8
 BNE DECIND1 
 INC XNEW,X
DECIND1 DEC INDN,X 
 BPL RVN 
STINN LDA INDINIT,X 
 STA INDN,X
RVN JSR RGTWALLCHK 
 RTS    
*
MFLCH LDX OPNUM
 LDA OPMODE0,X
 LSR A
 BCS YMFL
 LDA WIDTH
 LSR A
 CLC
 ADC XNEW,X
 BEQ YMFL   
 CMP #39
 BCS YMFL   
 STA TEMXX
 LDY YBOT
 LDA AHI,Y
 STA FLM+2
 LDA ALO,Y
 STA FLM+1
 LDX TEMXX
FLM LDA $2000,X ;CHANGEABLE
 BNE YMFL
 LDA #0
 STA MNFLF
 BEQ FLMO 
YMFL LDA #$80
 STA MNFLF
FLMO LDX OPNUM 
 BIT MNFLF     
OUTFLM RTS 
*
*
*
CAPTMSG LDA #$1A
 JSR MSG
 RTS
 ORG $6E00 
*
*
CHRTLUN1 LDA #$6D  
SEC STA OVSUB+1
 LDA #7
 STA OVS+1
 LDA #$FF
 STA CMX+1
 JMP OVS
*
*
CHRTLOW1 LDA #$98 
 STA OVSUB+1
 LDA #$F
 STA OVS+1
 LDA #7
 STA CMX+1
 JMP OVS
*
*
CHLFLUN1 LDA #$B6  
SED STA OVSUB+1
 LDA #7
 STA OVS+1
 LDA #$FF
 STA CMX+1
 JMP OVS
*
*
CHLFLOW1 LDA #$E1 
 STA OVSUB+1
 LDA #$F
 STA OVS+1
 LDA #7
 STA CMX+1
 JMP OVS
*
*
OVS LDX #7 ;CHANGEABLE 
OVS1 LDA LEVOP,X
 CMP LEV
 BNE OVNX  
 LDA OPMODE0,X
 AND #$80
 BEQ OVNX  
 LDA DELTA,X
 CMP #8 
 BCC OVSUB
 CMP #$FA
 BCC OVNX
OVSUB JSR $6E69 ;CHANGEABLE 
OVNX DEX 
CMX CPX #$FF ;CHANGEABLE 
 BNE OVS1
OUTOV RTS
*
CH48 LDA CHOLD,X
 CMP #$34
 BEQ DIS1
 CPX #4   
 BCC OUTCH48
 BEQ CH77
 CPX #8   
 BCS OUTCH48
DIS1 LDA DELTA,X
DIS11 CMP #4
 BEQ GO48
 CMP #5
 BEQ GO48
 BNE OUTCH48
CH77 LDA DELTA,X
 CMP #6
 BEQ GO48
 BNE DIS11
OUTCH48 RTS
GO48 JMP BEGONE
*
*
CH47 LDA CHOLD,X
 CPX #8   
 BCC OUTCH47
 BEQ DIS2
 CPX #$10 
 BCS OUTCH47
DIS2 LDA DELTA,X
 CMP #1
 BCC OUTCH47
 BEQ GO47
 CMP #4
 BCS OUTCH47
GO47 JMP BEGONE
OUTCH47 RTS
*
*
CH58 LDA CHOLD,X
 CMP #$44
 BEQ DIQ1
 CPX #4   
 BCC OUTCH58
 BEQ CH77N 
 CPX #8   
 BCS OUTCH58
DIQ1 LDA DELTA,X
DIQ11 CMP #$FB 
 BEQ GO58
 CMP #$FC 
 BEQ GO58
 BNE OUTCH58
CH77N LDA DELTA,X 
 CMP #$FD 
 BEQ GO58
 BNE DIQ11
OUTCH58 RTS
GO58 JMP BEGONE
*
*
CH57 LDA CHOLD,X
 CPX #8   
 BCC OUTCH57
 BEQ DIQ2
 CPX #$10 
 BCS OUTCH57
DIQ2 LDA DELTA,X
 CMP #$FE 
 BCC OUTCH57
 BEQ GO57
 CMP #$FC 
 BCS OUTCH57
GO57 JMP BEGONE
OUTCH57 RTS
*
*
*
*
*
 LST OFF
*
 ORG $E00
*************************
*
*  16 OPONENT VERSION
*
**************************
*
MN0Y DFB $8,$41,$78
MN1Y DFB $8,$41,$78  
MN2Y DFB $8,$41,$78  
MN3Y DFB $8,$41,$78  
MN4Y DFB $18,$51,$89
MN5Y DFB $18,$51,$89 
MN6Y DFB $18,$51,$89 
MN7Y DFB $18,$51,$89 
MN8Y DFB $28,$61,$99 
MN9Y DFB $28,$62,$99
MNAY DFB $28,$61,$99
MNBY DFB $28,$62,$99 
MNCY DFB $28,$61,$99 
MNDY DFB $28,$62,$99
MNEY DFB $28,$61,$99
MNFY DFB $28,$62,$99 
*   
LEVOP DFB 0,1,2,0,0,1,2,2,0,0,1,1,2,2,2,1
INDINIT DFB 4,4,4,4,3,3,3,3,2,2,2,2,2,2,2,2
OPWIDTH DFB 6,6,6,6,2,2,2,2,3,3,3,3,3,3,3,3
MNSTREINF DFB 2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2 
INDN DFB 0,1,2,3,0,1,2,3,0,1,2,3,0,1,2,3
*
OPFLG0 DFB 4
OPFLG1 DFB 1
OPFLG2 DFB 2
OPFLG3 DFB 4
OPFLG4 DFB 8
OPFLG5 DFB 16
OPFLG6 DFB 32
OPFLG7 DFB 64
OPFLG8 DFB 128
OPFLG9 DFB 1
OPFLGA DFB 2
OPFLGB DFB 4
OPFLGC DFB 8
OPFLGD DFB 16
OPFLGE DFB 32
OPFLGF DFB 64
*
OPMODE0 DFB 128
OPMODE1 DFB 128
OPMODE2 DFB 192
OPMODE3 DFB 128
OPMODE4 DFB 192
OPMODE5 DFB 128
OPMODE6 DFB 192
OPMODE7 DFB 128
OPMODE8 DFB 192
OPMODE9 DFB 128
OPMODEA DFB 192
OPMODEB DFB 128
OPMODEC DFB 192
OPMODED DFB 128
OPMODEE DFB 192
OPMODEF DFB 128
*
MNYTAB DFB 0,3,6,9,12,15,18,21,24,27,30,33,36,39,42,45
SNSEQTAB DFB $20,$28,$30,$38,$40,$48,$50,$58 
 DFB $60,$68,$70,$78,$80,$88,$90,$98 
*
CHOLD DFB $30,$31,$32,$33,$77,$78,$79,$7A 
 DFB $70,$76,$71,$75,$72,$74,$72,$74 
CHNEW DFB $30,$31,$32,$33,$77,$78,$79,$7A 
 DFB $70,$76,$71,$75,$72,$74,$72,$74 
XOLD DFB 34,20,30,40,50,60,70,44 
 DFB 43,45,47,40,50,60,70,42 
XNEW DFB 34,20,30,40,60,80,90,44                                  
 DFB 43,45,47,40,170,190,210,42      
YOLD DFB $8,$41,$78,$08,$18,$51,$89,$89 
 DFB $28,$28,$61,$61,$99,$99,$99,$61 
YNEW DFB $8,$41,$78,$08,$18,$51,$89,$89        
 DFB $28,$28,$61,$61,$99,$99,$99,$61 
*
MSEQ0 DFB $30,$31,$32,$31,$33,$31,$32,$34 
MSEQ1 DFB $30,$31,$32,$31,$33,$31,$32,$34 
MSEQ2 DFB $30,$31,$32,$31,$33,$31,$32,$34 
MSEQ3 DFB $30,$31,$32,$31,$33,$31,$32,$34 
MSEQ4 DFB $77,$78,$79,$7A,$77,$78,$79,$7A 
MSEQ5 DFB $77,$78,$79,$7A,$77,$78,$79,$7A 
MSEQ6 DFB $77,$78,$79,$7A,$77,$78,$79,$7A 
MSEQ7 DFB $77,$78,$79,$7A,$77,$78,$79,$7A 
MSEQ8 DFB $70,$71,$72,$70,$71,$72,$00,$00 
MSEQ9 DFB $70,$71,$72,$70,$71,$72,$00,$00 
MSEQA DFB $70,$71,$72,$70,$71,$72,$00,$00 
MSEQB DFB $76,$75,$74,$76,$75,$74,$00,$00 
MSEQC DFB $76,$75,$74,$76,$75,$74,$00,$00 
MSEQD DFB $76,$75,$74,$76,$75,$74,$00,$00 
MSEQE DFB $60,$61,$62,$60,$61,$62,$00,$00 
MSEQF DFB $60,$61,$62,$60,$61,$62,$00,$00 
*
FLGLO DFB $80,$81,$82,$83,$84,$85,$86,$87,$88,$89,$8A,$8B,$8C,$8D,$8E,$8F
MNMODE DFB $90,$91,$92,$93,$94,$95,$96,$97,$98,$99,$9A,$9B,$9C,$9D,$9E,$9F
*
MNSTRES DFB 4,4,4,4
*
HHFLG DFB $00
ALREADYFLG DFB 0,0
CAPTUREFLG DFB 0
SAFLG DFB 15
DELFIX DFB $18
BANN DFB 150
MANN DFB 110 
SANN DFB 90
*
